# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6
PYTHON_COMPAT=( python{3_3,3_4,3_5} )
VALA_MIN_API_VERSION="0.30"
VALA_USE_DEPEND="vapigen"

inherit gnome2 python-single-r1 vala virtualx

DESCRIPTION="Builder attempts to be an IDE for writing software for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Builder"

LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="clang git +introspection vala webkit"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

# FIXME: some unittests seem to hang forever
# When bumping, pay attention to all the included plugins/*/configure.ac files and the requirements within.
# Most have no extra requirements and default to enabled; we need to handle the ones with extra requirements, which tend to default to auto(magic)
# FIXME: >=dev-util/devhelp-3.20.0 dependency is automagic for devhelp integration plugin
# FIXME: vte could be optional via $(use_enable vte terminal-plugin) - but most/all people want this and have vte?
# FIXME: xdg-app-plugin needs xdg-app.pc >=0.4.11
# Python is always enabled - the core python plugin support checks are automagic and not worth crippling it by not supporting python plugins
RDEPEND="
	>=dev-libs/glib-2.47.92:2[dbus]
	git? (
		dev-libs/libgit2[ssh,threads]
		>=dev-libs/libgit2-glib-0.24.0[ssh] )
	>=dev-libs/libpeas-1.18.0
	>=dev-libs/libxml2-2.9
	dev-util/uncrustify
	>=x11-libs/pango-1.38.0
	>=x11-libs/gtk+-3.20.0:3[introspection?]
	>=x11-libs/gtksourceview-3.17.7:3.0[introspection?]
	introspection? ( >=dev-libs/gobject-introspection-1.47.92:= )
	${PYTHON_DEPS}
	>=dev-python/pygobject-3.19.3:3
	vala? ( $(vala_depend) )
	>=x11-libs/vte-0.40.2:2.91
	webkit? ( >=net-libs/webkit-gtk-2.12.0:4= )
	clang? ( sys-devel/clang )
"
# desktop-file-utils for desktop-file-validate check in configure for 3.20.4
DEPEND="${RDEPEND}
	dev-libs/appstream-glib
	dev-util/desktop-file-utils
	>=dev-util/gtk-doc-am-1.11
	>=dev-util/intltool-0.50.1
	>=sys-devel/gettext-0.18
	virtual/pkgconfig
"

pkg_setup() {
	python-single-r1_pkg_setup
}

src_prepare() {
	use vala && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	export PYTHON3_CONFIG="$(python_get_PYTHON_CONFIG)"
	# There are no python dependencies for python-pack-plugin (C code that provides basic python auto-indenter)
	gnome2_src_configure \
		--enable-editorconfig \
		--enable-python-pack-plugin \
		--enable-terminal-plugin \
		$(use_enable introspection) \
		$(use_enable vala vala-pack-plugin) \
		$(use_enable webkit) \
		$(use_enable webkit html-preview-plugin) \
		$(use_enable clang clang-plugin) \
		$(use_enable git git-plugin) \
		--disable-xdg-app-plugin \
		--disable-static
}

src_test() {
	# FIXME: this should be handled at eclass level
	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data/gsettings" || die

	GSETTINGS_SCHEMA_DIR="${S}/data/gsettings" virtx emake check
}